{*******************************************************}
{                                                       }
{  Responsive Software     http://www.responsive.co.nz  }
{                                                       }
{  Copyright (c) 2003-2006 Responsive Software Limited  }
{                                                       }
{*******************************************************}

unit HTTPResponder;

interface

uses
  IBDatabase, Classes;

function GetHTTPResponse
  (Method : string;
   URI : string;
   Version : string;
   MessageHeaders : TStringList;
   MessageBody : string) : string;

implementation

uses
  SyncObjs, Forms, Windows,
  Graphics, Chart, Series, TeEngine, Jpeg, 
  SysUtils, Utilities, HTTPUtilities, HTTPServerCommunicatorUnit,
  GeneralUtilities, Globals, DatabaseObjects, DatabaseManager;
  
{***** General formatting utilities *******************************************}

var
  // set this global variable to false before calling a procedure which
  // modifies the contents of a file by replacing tags
  // and then test to see whether or not any were actually replaced
  TagReplaced : boolean;

procedure ReplaceTag
  (Tag : string;
   Value : string;
   var Content : string);
begin
  if Pos(Tag,Content) <> 0 then
  begin
    Content := ReplaceSubstring(Tag,Value,Content);
    TagReplaced := true;
  end;
end;

function GetFileName
  (URI : string;
   Host : string) : string;
var
  QuestionMarkPos : integer;
begin
  QuestionMarkPos := Pos('?',URI);
  if QuestionMarkPos > 0 then
    Result := Copy(URI,1,QuestionMarkPos-1)
  else
    Result := URI;
  Result := AppendBackslash(GlobalConfiguration.WebsiteContentDirectory)
    + Host + Result;
  Result := ReplaceChar('/','\',Result);
  Result := ReplaceSubstring('%20',' ',Result);
end;

{***** Methods that must be synchronized with the main VCL thread *************}

function ConvertChartToJPG
  (Chart : TChart) : string;
var
  StringStream : TStringStream;
  Bitmap : TBitmap;
  JPEGImage : TJPEGImage;
begin
  StringStream := TStringStream.Create('');
  Bitmap := TBitmap.Create;
  JPEGImage := TJPEGImage.Create;
  try
    JPEGImage.CompressionQuality := 65;
    Bitmap.Width := Chart.Width;
    Bitmap.Height := Chart.Height;
    Chart.Draw(Bitmap.Canvas,Rect(0,0,Chart.Width,Chart.Height));
    JPEGImage.Assign(Bitmap);
    Bitmap.Dormant;
    // transfer jpeg image data to string
    JPEGImage.SaveToStream(StringStream);
    // extract result from data string
    Result := StringStream.DataString;
  finally
    JPEGImage.Free;
    Bitmap.Free;
    StringStream.Free;
  end;
end;

{***** Original HTML Response routines ****************************************}

const
  Spacer = '&nbsp;&nbsp;';

{***** Main Screen ************************************************************}

function CreateMainScreen : string;
begin
  // header
  Result := HTMLPageHeader;

  // details
  if GlobalConfiguration.POS then
    Result := Result + '<p><b><center><a href="items">Items</a></center></b></p>'
                     + '<p><b><center><a href="salesselect">Sales</a></center></b></p>';
  if GlobalConfiguration.Accounts then
    Result := Result + '<p><b><center><a href="accountsselect">Accounts</a></center></b></p>';

  // footer
  Result := Result + HTMLPageFooter;
end;

{***** Items Screen ***********************************************************}

function CreateItemsScreen : string;
var
  SelectionString : string;
  Items : TDatabaseObjectCollection;
  Item : TItem;
  i : integer;
  ImageStr : string;
begin
  // header
  Result := HTMLPageHeader;

  // load collection of items
  SelectionString := 'ORDER BY ' + DelimitSQLFieldName('Name');

  Items := nil;
  LoadSomeDatabaseObjects(Items,TItem,SelectionString);
  try
    Result := Result + '<p><b>Items</b></p>';
    Result := Result + '<table border = "1">';
    for i := 0 to Items.Count - 1 do
    begin
      Item := TItem(Items[i]);
      if Item.Active then
      begin
        if Item.Picture.AttachmentId = 0 then
          ImageStr := ''
        else
          ImageStr := '<img src="attach-' + IntToStr(Item.Picture.AttachmentId) + ExtractFileExt(Item.Picture.FileName) + '" height="100">';
        Result := Result + '<tr><td>' + Item.Name
                         + '</td><td>' + ConvertDoubleToString(Item.Price)
                         + '</td><td>' + ImageStr
                         + '</td></tr>';
      end;
    end;
    Result := Result  + '</table>';
  finally
    Items.Free;
  end;

  // footer
  Result := Result + HTMLPageFooter;
end;

{***** Sales Screens **********************************************************}

function CreateSalesSelectScreen : string;
begin
  // header
  Result := HTMLPageHeader;

  // details
  Result := Result
    + '<form name="input" action="salesresult" method="get">'

    + '<br>'
    + '<br>'
    + 'Salesperson' + Spacer
    + '<select name="salesperson">' + SalespersonOptions + '</select>'

    + '<br>'
    + '<br>'
    + 'Begin Period' + Spacer
    + '<select name="beginday">' + DayOptions + '</select>'
    + '<select name="beginmonth">' + MonthOptions + '</select>'
    + '<select name="beginyear">' + YearOptions + '</select>'

    + '<br>'
    + '<br>'
    + 'End Period' + Spacer
    + '<select name="endday">' + DayOptions + '</select>'
    + '<select name="endmonth">' + MonthOptions + '</select>'
    + '<select name="endyear">' + YearOptions + '</select>'

    + '<br>'
    + '<br>'
    + '<center><input type="submit" value="Show Sales"></center>'
    + '</form>';

  // footer
  Result := Result + HTMLPageFooter;
end;

function CreateSalesResultScreen
  (Parameters : TStringList) : string;
var
  SelectionString : string;
  Sales : TDatabaseObjectCollection;
  Sale : TSale;
  i : integer;
  BeginDate, EndDate : TDateTime;
  SalespersonId : int64;
  TotalTotalPrice : int64;
begin
  // header
  Result := HTMLPageHeader;

  // load collection of sales
  try
    BeginDate := EncodeDate(
      StrToInt(Parameters.Values['beginyear']),
      StrToInt(Parameters.Values['beginmonth']),
      StrToInt(Parameters.Values['beginday']));
  except
    BeginDate := Date;
  end;
  try
    EndDate := EncodeDate(
      StrToInt(Parameters.Values['endyear']),
      StrToInt(Parameters.Values['endmonth']),
      StrToInt(Parameters.Values['endday']));
  except
    EndDate := Date;
  end;
  if Firebird then
    SelectionString := 'WHERE ' + DelimitSQLFieldName('Date') + ' >= ' + DelimitSQLStringValue(ConvertDateToDatabaseString(BeginDate))
      + ' AND ' + DelimitSQLFieldName('Date') + ' <= ' + DelimitSQLStringValue(ConvertDateToDatabaseString(EndDate))
  else
    SelectionString := 'WHERE Sale."Date" >= ' + DelimitSQLStringValue(ConvertDateToDatabaseString(BeginDate))
      + ' AND Sale."Date" <= ' + DelimitSQLStringValue(ConvertDateToDatabaseString(EndDate));
  SalespersonId := StrToIntDef(Parameters.Values['salesperson'],0);
  if SalespersonId <> 0 then
    SelectionString := SelectionString + ' AND ' + DelimitSQLFieldName('SalespersonId') + ' = ' + IntToStr(SalespersonId);
  if Firebird then
    SelectionString := SelectionString + ' ORDER BY ' + DelimitSQLFieldName('Date') + ', ' + DelimitSQLFieldName('Time')
  else
    SelectionString := SelectionString + ' ORDER BY Sale."Date", Sale."Time"';

  Sales := nil;
  LoadSomeDatabaseObjects(Sales,TSale,SelectionString);
  try

    Result := Result + '<p><b>Sales for period ' + FormatDate(BeginDate) + ' to ' + FormatDate(EndDate) + '</b></p>';
    if SalespersonId <> 0 then
      Result := Result + '<p><b>Salesperson: ' + SalespersonName(SalespersonId) + '</b></p>';

    Result := Result + '<table border = "1">';
    Result := Result + '<tr>'
      + '<td>Date</td>'
      + '<td>Time</td>'
      + '<td>Salesperson</td>'
      + '<td>Total Price</td>'
      + '<td>Items</td>'
      + '<td>Payment Type</td>'
      + '</tr>';
    TotalTotalPrice := 0;
    for i := Sales.Count - 1 downto 0 do
    begin
      Sale := TSale(Sales[i]);
      Sale.LoadDetails;
      Result := Result + '<tr>'
        + '<td>' + Format('%-8.8s',[ShortFormatDate(Sale.Date)]) + '</td>'
        + '<td>' + FormatDateTime('hh:mm:ss',Sale.Time) + '</td>'
        + '<td>' + Format('%-15.15s ',[SalespersonName(Sale.SalespersonId)]) + '</td>'
        + '<td>' + Format(' %15.15s',[FormatCurrencyForDisplay(Sale.TotalPrice)]) + '</td>'
        + '<td>' + Format('  %-35.35s ',[Sale.SaleItemsAsString]) + '</td>'
        + '<td>' + Format('  %-25.25s ',[Sale.PaymentItemsAsString]) + '</td>'
        + '</tr>';
      TotalTotalPrice := TotalTotalPrice + Sale.TotalPrice;
    end;
    Result := Result + '<tr>'
      + '<td></td>'
      + '<td></td>'
      + '<td>TOTAL</td>'
      + '<td>' + Format(' %15.15s',[FormatCurrencyForDisplay(TotalTotalPrice)]) + '</td>'
      + '<td></td>'
      + '<td></td>'
      + '</tr>';
    Result := Result  + '</table>';

  finally
    Sales.Free;
  end;

  // footer
  Result := Result + HTMLPageFooter;
end;

{***** Accounts Screens *******************************************************}

function CreateAccountsSelectScreen : string;
   
  function ReportTypeOptions : string;
  begin
    Result := '';
    Result := Result + '<option value="income">Income Statement';
    Result := Result + '<option value="balance">Balance Sheet';
  end;

begin
  // header
  Result := HTMLPageHeader;

  // details
  Result := Result
    + '<form name="input" action="accountsresult" method="get">'

    + '<br>'
    + '<br>'
    + 'Company' + Spacer
    + '<select name="company">' + CompanyOptions + '</select>'

    + '<br>'
    + '<br>'
    + 'Report' + Spacer
    + '<select name="reporttype">' + ReportTypeOptions + '</select>'

    + '<br>'
    + '<br>'
    + 'Begin Period' + Spacer
    + '<select name="beginday">' + DayOptions + '</select>'
    + '<select name="beginmonth">' + MonthOptions + '</select>'
    + '<select name="beginyear">' + YearOptions + '</select>'

    + '<br>'
    + '<br>'
    + 'End Period' + Spacer
    + '<select name="endday">' + DayOptions + '</select>'
    + '<select name="endmonth">' + MonthOptions + '</select>'
    + '<select name="endyear">' + YearOptions + '</select>'

    + '<br>'
    + '<br>'
    + '<center><input type="submit" value="Show Report"></center>'
    + '</form>';

  // footer
  Result := Result + HTMLPageFooter;
end;

function CompareAccounts
  (Item1, Item2 : pointer) : integer;
var
  Account1,
  Account2 : TAccount;
begin
  Account1 := TAccount(Item1);
  Account2 := TAccount(Item2);
  if (Account1 = nil) and (Account2 = nil) then
    Result := 0
  else if (Account1 = nil) and (Account2 <> nil) then
    Result := -1
  else if (Account1 <> nil) and (Account2 = nil) then
    Result := 1
  else begin
    // compare on account type
    Result := integer(Account1.AccountType)
      - integer(Account2.AccountType);
    // if same then use account name
    if Result = 0 then
      Result := CompareText(
        Account1.Name,
        Account2.Name);
  end;
end;

function CreateAccountsResultScreen
  (Parameters : TStringList) : string;
var
  SelectionString : string;
  Accounts : TDatabaseObjectCollection;
  Account : TAccount;
  i : integer;
  BeginDate, EndDate : TDateTime;
  CompanyId : int64;
  AccountBalance : int64;
  TotalBalance : int64;
  NetIncome : int64;

  function RetainedEarnings : int64;
  var
    i : integer;
    Account : TAccount;
    AccountBalance : int64;
  begin
    Result := 0;
    for i := 0 to Accounts.Count - 1 do
    begin
      Account := TAccount(Accounts[i]);
      if Account.IncomeStatement then
      begin
        AccountBalance := Account.BalanceAsAt(EndDate);
        // reverse the sign on debit accounts
        if Account.Debit then
          AccountBalance := -AccountBalance;
        // accumulate balances
        Result := Result + AccountBalance;
      end;
    end;
  end;

  function ConvertAccountTypeToDescription
    (AccountType : TAccountType) : string;
  begin
    if AccountType = atAsset then
      Result := 'TOTAL ASSETS'
    else if AccountType = atLiability then
      Result := 'TOTAL LIABILITIES'
    else if AccountType = atEquity then
      Result := 'TOTAL EQUITY'
    else if AccountType = atIncome then
      Result := 'TOTAL INCOME'
    else if AccountType = atExpense then
      Result := 'TOTAL EXPENSES';
  end;

begin
  // header
  Result := Result + HTMLPageHeader;

  // extract data parameters
  try
    BeginDate := EncodeDate(
      StrToInt(Parameters.Values['beginyear']),
      StrToInt(Parameters.Values['beginmonth']),
      StrToInt(Parameters.Values['beginday']));
  except
    BeginDate := Date;
  end;
  try
    EndDate := EncodeDate(
      StrToInt(Parameters.Values['endyear']),
      StrToInt(Parameters.Values['endmonth']),
      StrToInt(Parameters.Values['endday']));
  except
    EndDate := Date;
  end;
  // load collection of accounts
  CompanyId := StrToIntDef(Parameters.Values['company'],0);
  SelectionString := 'WHERE ' + DelimitSQLFieldName('CompanyId') + ' = ' + IntToStr(CompanyId);

  Accounts := nil;
  LoadSomeDatabaseObjects(Accounts,TAccount,SelectionString);
  Accounts.Sort(CompareAccounts);
  try

    if Parameters.Values['reporttype'] = 'income' then
    begin
      Result := Result + '<p><b>Income Statement for period ' + FormatDate(BeginDate) + ' to ' + FormatDate(EndDate) + '</b></p>';
      if CompanyId <> 0 then
        Result := Result + '<p><b>Company: ' + CompanyName(CompanyId) + '</b></p>'
      else
        Result := Result + '<p><b>Company: Default</b></p>';

      Result := Result + '<table border = "1">';
      Result := Result + '<tr>'
        + '<td>ACCOUNT</td>'
        + '<td>TOTAL</td>'
        + '</tr>';
      TotalBalance := 0;
      NetIncome := 0;
      for i := 0 to Accounts.Count - 1 do
      begin
        Account := TAccount(Accounts[i]);
        if Account.IncomeStatement then
        begin
          Account.LoadEntries;
          AccountBalance := Account.Balance(true,BeginDate,true,EndDate);
          if AccountBalance <> 0 then
          begin
            Result := Result + '<tr>'
              + '<td>' + Account.Name + '</td>'
              + '<td>' + Format(' %15.15s',[FormatCurrencyForDisplay(AccountBalance)]) + '</td>'
              + '</tr>';
            TotalBalance := TotalBalance + AccountBalance;
          end;
        end;
        // show total when account type changes
        if (i = Accounts.Count - 1)
          or (TAccount(Accounts[i+1]).AccountType <> Account.AccountType) then
        begin
          if TotalBalance <> 0 then
          begin
            Result := Result + '<tr>'
              + '<td>' + ConvertAccountTypeToDescription(Account.AccountType) + '</td>'
              + '<td>' + Format(' %15.15s',[FormatCurrencyForDisplay(TotalBalance)]) + '</td>'
              + '</tr>';
            if Account.AccountType = atExpense then
              NetIncome := NetIncome - TotalBalance
            else
              NetIncome := NetIncome + TotalBalance;
            TotalBalance := 0;
          end;
        end;
      end;
      // show final total
      if TotalBalance <> 0 then
      begin
        Result := Result + '<tr>'
          + '<td>' + ConvertAccountTypeToDescription(atExpense) + '</td>'
          + '<td>' + Format(' %15.15s',[FormatCurrencyForDisplay(TotalBalance)]) + '</td>'
          + '</tr>';
        NetIncome := NetIncome - TotalBalance;
      end;
      // show net income item
      Result := Result + '<tr>'
        + '<td>NET INCOME</td>'
        + '<td>' + Format(' %15.15s',[FormatCurrencyForDisplay(NetIncome)]) + '</td>'
        + '</tr>';
      Result := Result  + '</table>';
    end else begin
      Result := Result + '<p><b>Balance Sheet as at ' + FormatDate(EndDate) + '</b></p>';
      if CompanyId <> 0 then
        Result := Result + '<p><b>Company: ' + CompanyName(CompanyId) + '</b></p>'
      else
        Result := Result + '<p><b>Company: Default</b></p>';

      Result := Result + '<table border = "1">';
      Result := Result + '<tr>'
        + '<td>ACCOUNT</td>'
        + '<td>TOTAL</td>'
        + '</tr>';
      TotalBalance := 0;
      for i := 0 to Accounts.Count - 1 do
      begin
        Account := TAccount(Accounts[i]);
        Account.LoadEntries;
        if Account.BalanceSheet then
        begin
          AccountBalance := Account.BalanceAsAt(EndDate);
          if AccountBalance <> 0 then
          begin
            Result := Result + '<tr>'
              + '<td>' + Account.Name + '</td>'
              + '<td>' + Format(' %15.15s',[FormatCurrencyForDisplay(AccountBalance)]) + '</td>'
              + '</tr>';
            TotalBalance := TotalBalance + AccountBalance;
          end;
        end;
        // show total when account type changes
        if ((i = Accounts.Count - 1)
          or (TAccount(Accounts[i+1]).AccountType <> Account.AccountType))
          and (Account.AccountType in [atAsset,atLiability]) then
        begin
          if TotalBalance <> 0 then
          begin
            Result := Result + '<tr>'
              + '<td>' + ConvertAccountTypeToDescription(Account.AccountType) + '</td>'
              + '<td>' + Format(' %15.15s',[FormatCurrencyForDisplay(TotalBalance)]) + '</td>'
              + '</tr>';
            TotalBalance := 0;
          end;
        end;
      end;
      // handle retained earnings as if it is an equity account
      AccountBalance := RetainedEarnings;
      if AccountBalance <> 0 then
      begin
        Result := Result + '<tr>'
          + '<td>Retained Earnings</td>'
          + '<td>' + Format(' %15.15s',[FormatCurrencyForDisplay(AccountBalance)]) + '</td>'
          + '</tr>';
        TotalBalance := TotalBalance + AccountBalance;
      end;
      // show final total
      if TotalBalance <> 0 then
        Result := Result + '<tr>'
          + '<td>' + ConvertAccountTypeToDescription(atEquity) + '</td>'
          + '<td>' + Format(' %15.15s',[FormatCurrencyForDisplay(TotalBalance)]) + '</td>'
          + '</tr>';
      Result := Result  + '</table>';
    end;
  finally
    Accounts.Free;
  end;

  // footer
  Result := Result + HTMLPageFooter;
end;

{***** Earlier routines used to build default content *************************}

function GetHTMLResponse
  (URI : string) : string;
var
  QuestionMarkPos : integer;
  PageName : string;
  Parameters : TStringList;
begin
  QuestionMarkPos := Pos('?',URI);
  if QuestionMarkPos > 0 then
  begin
    PageName := Copy(URI,1,QuestionMarkPos-1);
    Delete(URI,1,QuestionMarkPos);
    Parameters := TStringList.Create;
    SplitStrings(Parameters,URI,'&');
  end else begin
    PageName := URI;
    Parameters := nil;
  end;
  try
    if PageName = '/' then
      Result := CreateMainScreen
    else if PageName = '/items' then
      Result := CreateItemsScreen
    else if PageName = '/salesselect' then
      Result := CreateSalesSelectScreen
    else if PageName = '/salesresult' then
      Result := CreateSalesResultScreen(Parameters)
    else if PageName = '/accountsselect' then
      Result := CreateAccountsSelectScreen
    else if PageName = '/accountsresult' then
      Result := CreateAccountsResultScreen(Parameters)
    else
      Result := '';
  finally
    Parameters.Free;
  end;
end;

function GetContent
  (URI : string) : string;
var
  AttachmentId : int64;
begin
  Delete(URI,1,Pos('-',URI));
  Delete(URI,Pos('.',URI),Length(URI));
  AttachmentId := StrToInt64Def(URI,0);
  Result := AttachmentCacheManager.GetFileContents(AttachmentId);
end;

procedure GenerateDefaultContent
  (URI : string;
   var Content : string;
   var DateLastModified : TDateTime);
begin
  if Pos('/attach-',URI) = 1 then
    Content := GetContent(URI)
  else
    Content := GetHTMLResponse(URI);
  DateLastModified := NowGMT;
end;

{******************************************************************************}

procedure GenerateContentDynamically
  (URI : string;
   Parameters : TStringList;
   Host : string;
   var Content : string);
begin
  Content := '';
  
  // add code here to create dynamic content e.g. JPG images
  
end;

{******************************************************************************}

procedure GenerateContentFromFile
  (URI : string;
   Parameters : TStringList;
   Host : string;
   var Content : string;
   var FileName : string;
   var Modified : boolean);
begin
  FileName := GetFileName(URI,Host);
  Content := GetFileContents(FileName);
  Modified := false;
  
  TagReplaced := false;

  // add code here to make dynamic modifications to file

  if TagReplaced then
    Modified := true;
end;

{***** General utilities used to build HTTP response **************************}

procedure GenerateContent
  (URI : string;
   Parameters : TStringList;
   Host : string;
   var Content : string;
   var DateLastModified : TDateTime);
var
  FileName : string;
  Modified : boolean;
begin
  // handle default '/' request
  if URI = '/' then
  begin
    FileName := GetFileName('/index.html',Host);
    Content := GetFileContents(FileName);
    if Content = '' then
    begin
      FileName := GetFileName('/index.htm',Host);
      Content := GetFileContents(FileName);
    end;
    if Content <> '' then
      DateLastModified := FileDateToDateTime(FileAge(FileName));
    Exit;
  end;
  // handle requests for dynamically generated objects
  GenerateContentDynamically(URI,Parameters,Host,Content);
  if Content <> '' then
  begin
    DateLastModified := Now;
    Exit;
  end;
  // handle requests for files located in the web content directory
  GenerateContentFromFile(URI,Parameters,Host,Content,FileName,Modified);
  // determine date file was last modified
  if Modified then
    DateLastModified := Now
  else if Content <> '' then
    DateLastModified := FileDateToDateTime(FileAge(FileName));
end;

procedure GetParameters
  (URI : string;
   var Parameters : TStringList);
var
  QuestionMarkPos : integer;
begin
  QuestionMarkPos := Pos('?',URI);
  if QuestionMarkPos > 0 then
  begin
    Delete(URI,1,QuestionMarkPos);
    Parameters := TStringList.Create;
    SplitStrings(Parameters,URI,'&');
  end else
    Parameters := nil;
end;

function GetContentType
  (URI : string) : string;
var
  FileExtension : string;
begin
  FileExtension := UpperCase(ExtractFileExt(URI));
  if FileExtension = '.BMP' then
    Result := 'image/x-ms-bmp'
  else if FileExtension = '.ICO' then
    Result := 'image/x-icon'
  else if FileExtension = '.WMF' then
    Result := 'image/wmf'
  else if FileExtension = '.DOC' then
    Result := 'application/msword'
  else if FileExtension = '.XLS' then
    Result := 'application/vnd.ms-excel'
  else if FileExtension = '.PDF' then
    Result := 'application/pdf'
  else if (FileExtension = '.JPG')
         or (FileExtension = '.JPE')
         or (FileExtension = '.JPEG') then
    Result := 'image/jpeg'
  else
    Result := '';
end;

function GetHTTPResponse
  (Method : string;
   URI : string;
   Version : string;
   MessageHeaders : TStringList;
   MessageBody : string) : string;
var
  Content : string;
  Parameters : TStringList;
  DateLastModified : TDateTime;

  function HostHeaderPresent : boolean;
  var
    i : integer;
  begin
    for i := 0 to MessageHeaders.Count - 1 do
      if Pos('HOST:',UpperCase(MessageHeaders[i])) = 1 then
      begin
        Result := true;
        Exit;
      end;
    Result := false;
  end;

  function Host : string;
  var
    i : integer;
  begin
    for i := 0 to MessageHeaders.Count - 1 do
      if Pos('HOST:',UpperCase(MessageHeaders[i])) = 1 then
      begin
        // remove field name at beginning of string
        Result := Trim(Copy(MessageHeaders[i],6,Length(MessageHeaders[i])));
        // remove port number if present
        if Pos(':',Result) <> 0 then
          Delete(Result,Pos(':',Result),Length(Result));
        Exit;
      end;
    Result := '';
  end;

begin
  Parameters := nil;
  try
    try
      if (Method = 'GET') or (Method = 'HEAD') then
      begin
        // if Host header is not present then return response
        // as required by HTTP specification
        if not HostHeaderPresent then
        begin
          Result := 'HTTP/1.1 400 Bad Request' + CRLF;
          Result := Result + 'Server: ' + ProgramName + ' Server' + CRLF;
          Result := Result + 'Connection: close' + CRLF;
        end else begin
          // extract parameters from URI
          GetParameters(URI,Parameters);
          // generate appropriate content
          GenerateContent(URI,Parameters,Host,Content,DateLastModified);
          // if content not generated then use earlier default demo routines
          // that generate all content dynamically
          if Content = '' then
            GenerateDefaultContent(URI,Content,DateLastModified);
          // if file not found or no content generated then return appropriate
          // HTTP error response
          if Content = '' then
          begin
            Result := 'HTTP/1.1 404 Not Found' + CRLF;
            Result := Result + 'Server: ' + ProgramName + ' Server' + CRLF;
            Result := Result + 'Connection: close' + CRLF;
          end else begin
            Result := 'HTTP/1.1 200 OK' + CRLF;
            Result := Result + 'Server: ' + ProgramName + ' Server' + CRLF;
            Result := Result + 'Connection: close' + CRLF;
            Result := Result + 'Last-Modified: '
              + FormatDateTime('ddd, dd mmm yyyy hh:mm:ss',DateLastModified)
              + ' GMT' + CRLF;
            Result := Result + 'Content-Type: ' + GetContentType(URI) + CRLF;
            Result := Result + 'Content-Length: '
              + IntToStr(Length(Content)) + CRLF;
            // add body only if GET
            if Method = 'GET' then
              Result := Result + CRLF + Content;
          end;
        end;
      end else begin
        Result := 'HTTP/1.1 501 Not Implemented' + CRLF;
        Result := Result + 'Server: ' + ProgramName + ' Server' + CRLF;
        Result := Result + 'Connection: close' + CRLF;
      end;
    except
      on E:Exception do
      begin
        Result := 'HTTP/1.1 500 Server Error' + CRLF;
        Result := Result + 'Server: ' + ProgramName + ' Server' + CRLF;
        Result := Result + 'Connection: close' + CRLF;
        if ServerLogging then
          MessageLog.Log('Server processing error - ' + E.Message);
      end;
    end;
  finally
    Parameters.Free; 
  end;
end;

end.